List ID3 metadata tags from mp3 or wma files using VB Script

Next simple VB Script function written for WSH/Wscript (.vbs file) let's you list all your media files (.mp3, .wma) from your disk, collect metadata id3 tags. You can write the data to a database, print them out or other action.
This code is using CDDBControl.dll, which is suplied with Creative SoundBlaster extigy drivers and software.


'List of all mp3 files In one folder
'Read it's id3 tags
'2005 Antonin Foller, Motobit Software
Sub ListID3Tags(sFolder)
  'get FileSystemObject To enumerate files
  Dim FS: Set FS = CreateObject("Scripting.FileSystemObject")
  
  'call ListID3TagsFS Function with a folder object
  ListID3TagsFS FS.GetFolder(sFolder)
End Sub

Sub ListID3TagsFS(Root)
  Dim SubFolder, File
  
  'enumerate all files In the folder
  For Each File In Root.Files
    'select only mp3 And wma files
    Select Case LCase(Right(File.Name, 4))
      Case ".mp3", ".wma": ListID3TagsFile File
    End Select
  Next

  'process all subfolders
  For Each SubFolder In Root.SubFolders
    ListID3TagsFS SubFolder
  Next
End Sub

Sub ListID3TagsFile(File)
  'Get id3 object To change data
  Dim id3: Set id3 = CreateObject("CDDBControl.CddbID3Tag")

  'load id3 data from a file, read only
  id3.LoadFromFile File.Path, True
  
  'print some of id3 tags
  WScript.Echo File.Name, id3.Album, id3.Title, id3.LeadArtist
End Sub

Copyright and use this code

The source code on this page and other samples at https://www.motobit.com/tips/ are a free code, you can use it as you want: copy it, modify it, use it in your products, ...

If you use this code, please:

1. Leave the author note in the source.

2. Link this sample from you page.

<A
 Href="https://www.motobit.com/tips/detpg_list-id3-tags-script/"
 Title="Let's you list all your media
	files and collect metadata tags
	from the files."
>List ID3 metadata tags from mp3 or wma files using VB Script</A>

List ID3 metadata tags from mp3 or wma files using VB ScriptMOTOBIT.COM

See also

Copyright and use this code