GetCommandLine Win32 function for VBA/VB

I needed the GetCommandLine function for VBA several times, but I cannot find any working code of the Win32 api function on net. You cannot simply use App.ExeName property or Command function, because these two VBA methods does not work if you create VBA COM DLL project.

You also cannot directly use GetCommandLine in VBA declaration, something like

Declare Function GetCommandLine Lib "kernel32" Alias "GetCommandLineA" () As string

This simple code do not work, because GetCommandLine returns a pointer to string, which VBA cannot handle directly. You have to use another Win32 functions, which works with pointers. I have choosen lstrlenA to get a length of the command line string and lstrcpynA to copy command line to a VBA buffer.

Declare Function lstrcpyn_long_string Lib "kernel32" Alias "lstrcpynA" (ByVal DestString As String, ByVal SourcePointer As Long, ByVal MaxLen As Long) As Long
Declare Function lstrlen_long Lib "kernel32" Alias "lstrlenA" (ByVal SourcePointer As Long) As Long
Declare Function GetCommandLine_long Lib "kernel32" Alias "GetCommandLineA" () As Long

'GetCommandLine VBA function
' 2008 Antonin Foller, www.motobit.com
Function GetCommandLine() As String
  'Get a pointer to process commandline as Long
  Dim ptrCommandLine As Long
  ptrCommandLine = GetCommandLine_long
  If ptrCommandLine > 0 Then 'GetCommandLine ok
    Dim Buffer As String, BufferLength As Long
    'Get a length of the command line using Long pointer
    'Returns the length without the zero terminating char
    BufferLength = lstrlen_long(ptrCommandLine)
    
    If BufferLength > 0 Then
      'Allocate a space for the command line
      Buffer = Space(BufferLength + 1)
      
      'Copy the command line to a buffer using Long + String pointers.
      ptrCommandLine = lstrcpyn_long_string(Buffer, ptrCommandLine, BufferLength + 1)
      
      'The copy SHOULD be OK. Zero means some error, not enough of space
      If ptrCommandLine > 0 Then 'lstrcpyn
        'Remove the zero terminator from the copied string
        Dim PosZero As Long
        PosZero = InStr(Buffer, Chr$(0))
        If PosZero > 0 Then Buffer = Left(Buffer, PosZero - 1)
        GetCommandLine = Buffer
      End If 'If ptrCommandLine > 0 Then 'lstrcpyn
    End If 'If BufferLength > 0 Then
  End If 'If ptrCommandLine > 0 Then 'GetCommandLine ok
End Function

Copyright and use this code

The source code on this page and other samples at https://www.motobit.com/tips/ are a free code, you can use it as you want: copy it, modify it, use it in your products, ...

If you use this code, please:

1. Leave the author note in the source.

2. Link this sample from you page.

<A
 Href="https://www.motobit.com/tips/detpg_vba-getcommandline/"
 Title="Code to call GetCommandLine function from
	VBA  - Excel, Word
	and other software with Visual
	Basic"
>GetCommandLine Win32 function for VBA/VB</A>

GetCommandLine Win32 function for VBA/VBMOTOBIT.COM

See also

Copyright and use this code