| Do you like this article? Please, rate it and write review! Rated: by Aspin.com users |
'VBScript QuotedPrintableDecode decoding Function
'2005 Antonin Foller http://www.motobit.com
Function QuotedPrintableDecode(SourceData, CharSet)
'Create CDO.Message object For the encoding.
Dim Message: Set Message = CreateObject("CDO.Message")
'Set the encoding
Message.BodyPart.ContentTransferEncoding = "quoted-printable"
'Get the data stream To write source string data
Dim Stream 'As ADODB.Stream
Set Stream = Message.BodyPart.GetEncodedContentStream
If VarType(SourceData) = vbString Then
'Set charset To base windows charset
Stream.charset = "windows-1250"
'Write the VBScript string To the stream.
Stream.WriteText SourceData
Else
'Set the type of the stream To adTypeBinary.
Stream.Type = 1
'Write the source binary data To the stream.
Stream.Write SourceData
End If
'Store the data To the message BodyPart
Stream.Flush
'Get an encoded stream
Set Stream = Message.BodyPart.GetDecodedContentStream
'Set the type of the stream To adTypeBinary.
Stream.CharSet = CharSet
'You can use Read method To get a binary data.
QuotedPrintableDecode = Stream.ReadText
End Function
|
'VBScript QuotedPrintableDecode_Binary decoding Function
'2005 Antonin Foller http://www.motobit.com
Function QuotedPrintableDecode_Binary(SourceData)
'Create CDO.Message object For the encoding.
Dim Message: Set Message = CreateObject("CDO.Message")
'Set the encoding
Message.BodyPart.ContentTransferEncoding = "quoted-printable"
'Get the data stream To write source string data
Dim Stream 'As ADODB.Stream
Set Stream = Message.BodyPart.GetEncodedContentStream
If VarType(SourceData) = vbString Then
'Write the VBScript string To the stream.
Stream.Write SourceData
Else
'Set the type of the stream To adTypeBinary.
Stream.Type = 1
'Write the source binary data To the stream.
Stream.Write SourceData
End If
'Store the data To the message BodyPart
Stream.Flush
'Get an encoded stream
Set Stream = Message.BodyPart.GetDecodedContentStream
'Set the type of the stream To adTypeBinary.
Stream.Type = 1
'You can use Read method To get a binary data.
QuotedPrintableDecode_Binary = Stream.Read
End Function
|
Quoted-printable
From Wikipedia, the free encyclopedia.
Quoted-printable is an encoding using printable characters, alphanumeric and the equals sign "=", to transmit 8bit data over a 7bit data path. It is defined as a MIME content transfer encoding for use in Internet e-mail.
Introduction
The basic Internet e-mail transmission protocol, SMTP, supports only ASCII characters (see also 8BITMIME). MIME defines mechanisms for sending other kinds of information in e-mail, including text in languages other than English using character encodings other than ASCII. However these encodings often use byte values outside the ASCII range so they need to be encoded further before they are suitable for use in e-mail. Quoted-printable encoding is one method used for mapping arbitary bytes into sequences of ASCII characters. This encoding is reversible, meaning the original bytes and hence the non-ASCII characters they represent can be recovered.
Quoted-printable and Base64 are the two basic MIME content transfer encodings. If the input text is mostly ASCII, quoted-printable results in a fairly readable and compact encoded result. On the other hand if the input is not mostly ASCII then quoted printable becomes both unreadable and extremely inefficient. Base64 is not readable but has a predictable overhead for all data and is the more sensible choice for binary formats or text in non latin based languages.
Quoted Printable Encoding
Any 8-bit byte value may be encoded with 3 characters, an "=" followed by two hexadecimal digits (0-9 or A-F) representing the byte's numeric value. For example, a US-ASCII form feed character (decimal value 12) can be represented by "=0C", and a US-ASCII equal sign (decimal value 61) is represented by "=3D". All characters except printable ASCII characters or end of line characters must be encoded in this fashion.
Printable ASCII characters except "=", i.e. those with decimal values between 33 and 126 excepting decimal value 61 (=), may be represented by themselves.
ASCII tab and space characters, decimal values 9 and 32, may be represented by themselves except if these characters appear at the end of a line. If one of these characters appears at the end of a line it must be encoded as "=09" (tab) or "=20" (space).
If the data being encoded contains meaningful line breaks, they must be encoded as an ASCII CR LF sequence, not as their original byte values. Conversely if byte values 10 and 13 have meanings other than end of line then they must be encoded as =0A and =0D.
Lines of quoted-printable encoded data must not be longer than 76 characters. To satisfy this requirement without altering the encoded text soft line breaks may be added as desired. A soft line break consists of an "=" at the end of an encoded line and does not cause a line break in the decoded text.
See also
Base64 encode VBS function (vb encoder algorithm), source codeSource of VBS (ASP) function that lets you encode source data (binary or string) to a base64 encoded string.
Base64 decode VBS function (vb decoder algorithm), source codeSource of VBS (ASP) function that enables decode base64 encoded strings.
Copyright and use this code
<A Href="http://www.motobit.com/tips/detpg_quoted-printable-decode/" Title="This article contains a short function for quoted printable decoding, using CDO.Message object." >Quoted-printable decode VBScript function.</A>